ここからはより実用的な使用法を想定する中で、まずはリレー動作を行なってみる。例としては、ポイントと連動したレイアウトの閉塞区間への電源供給オンオフ、等の用途である。実験用として用意したのは秋月電子の「ドライバー内蔵リレーモジュールキット」。キットなので簡単な半田付けが必要だが、基板上にドライバー回路も含まれているので、その分実装は楽になる。組み立て方、及び使い方は以下を参考にした。

電子工作の部屋 - ドライバ内蔵リレーモジュールキット (K-13573)

スケッチは前記事の物にリレー部分（Arduino時のコード）を追加したが、信号用のPIN番号が異なるのでそこは変えている。

[ スケッチ：Esp32_AsyncWebServer_Relay ]

#include <WiFi.h>
#include "ESPAsyncWebServer.h"
#include "SPIFFS.h"
#include <ArduinoJson.h>
const char ssid[] = "********";
const char pass[] = "********";
const IPAddress ip(192,168,3,17);
const IPAddress gateway(192,168,1,1);  // デフォルトゲートウェイ
const IPAddress subnet(255,255,255,0);
AsyncWebServer server(80);            // ポート設定
// Jsonオブジェクトの初期化
StaticJsonDocument<512> doc;
#define LED_PIN 33
#define REL_PIN 32  //リレー用
uint8_t led_status;  //LEDの状態制御用変数
void setup()
{
  Serial.begin(115200);
  pinMode(LED_PIN, OUTPUT); // GPIO33を出力設定に
  pinMode(REL_PIN, OUTPUT); // GPIO32を出力設定に
  // SPIFFSのセットアップ
  if(!SPIFFS.begin(true)){
    Serial.println("An Error has occurred while mounting SPIFFS");
    return;
  }
  WiFi.config(ip, gateway, subnet);
  WiFi.begin (ssid, pass);
  while ( WiFi.status() != WL_CONNECTED ) {
    delay ( 1000 );
    Serial.print ( "." );
  }
  // 各種情報を表示
  Serial.print("SSID: ");
  Serial.println(ssid);
  Serial.print("AP IP address: ");
  Serial.println(ip);
  // GETリクエストに対するハンドラーを登録
  // rootにアクセスされた時のレスポンス
  server.on("/", HTTP_GET, [](AsyncWebServerRequest *request){
    request->send(SPIFFS, "/index.html");
  });
  // style.cssにアクセスされた時のレスポンス
  server.on("/style.css", HTTP_GET, [](AsyncWebServerRequest *request){
    request->send(SPIFFS, "/style.css", "text/css");
  });
  // LED の制御変数の変更リクエスト
  server.on(
    "/post_test",
    HTTP_POST,
    [](AsyncWebServerRequest * request){},
    NULL,
    [](AsyncWebServerRequest * request, uint8_t *data, size_t len, size_t index, size_t total) {
      String resjson = "";
      for (size_t i = 0; i < len; i++) {
        //Serial.write(data[i]);
        resjson.concat(char(data[i]));
      }
      Serial.println(resjson);
      DeserializationError error = deserializeJson(doc, resjson);
      if(error){
        Serial.println("deserializeJson() faild");
        request->send(400);
      }
      else{
        led_status = doc["LED_STATUS"];       //zz Tilt Motor Default SPEED
        request->send(200);
      }
  });
  led_status = 0;
  // サーバースタート
  server.begin();
  Serial.println("Server start!");
}
void loop() {
  // LED&リレー状態変更
  if(led_status == 0){
    digitalWrite(LED_PIN, LOW);
    digitalWrite(REL_PIN, LOW);
  }
  else{
    digitalWrite(LED_PIN, HIGH);
    digitalWrite(REL_PIN, HIGH);
  }
}